PerlMagick, Perl API

インストール • 概要 • サンプルスクリプト • 画像の読み込みまたは書き込み • 画像の操作 • 画像属性の設定 • 画像属性の取得 • 画像と再構築の比較 • 画像モンタージュの作成 • ブロブの操作 • 画像ピクセルへの直接アクセス • その他のメソッド • 例外処理• 定数

PerlMagickは、ImageMagickに対するオブジェクト指向のPerlインターフェースです。このモジュールを使用すると、Perlスクリプト内から画像または画像シーケンスを読み込み、操作、または書き込むことができます。そのため、Web CGIスクリプトに非常に適しています。PerlMagickを適切にビルドするには、システムにImageMagick 6.5.5以上とPerlバージョン5.005_02以上がインストールされている必要があります。

PerlMagickの価値を示す多くの便利なスクリプトが利用可能です。MagickStudioを使用してWebベースの画像操作と変換を行ったり、L-システムを使用して数学的な構造を用いて植物の画像を作成したり、最後にWebMagick Image Navigatorを使用してサムネイル画像のコレクションをナビゲートして表示する画像を選択したりできます。

ImageMagick StudioでWebブラウザからPerlMagickを試すことができます。または、サンプルからPerlMagickの選択された機能を確認できます。

インストール

UNIX

PerlMagickは、システムRPMリポジトリから入手できますか？たとえば、CentOSシステムでは、このようにPerlMagickをインストールします

yum install ImageMagick-perl

そうでない場合は、ImageMagickソースディストリビューションからPerlMagickをインストールする必要があります。最新のソースリリースをダウンロードしてください。

次のコマンドでディストリビューションを展開します

tar xvzf ImageMagick.tar.gz

次に、ImageMagickを構成してコンパイルします

$ cd ImageMagick-7.1.1
$ ./configure -with-perl
$ make

ImageMagick / PerlMagickが問題なく構成およびコンパイルされたら、システムにインストールする準備ができています。インストールには管理者権限が必要です。インストールするには、次のように入力します

sudo make install

動的リンカのランタイムバインディングを構成する必要がある場合があります

sudo ldconfig /usr/local/lib

最後に、PerlMagickのインストールが正しく機能することを確認するには、次のように入力します

perl -MImage::Magick -le 'print Image::Magick->QuantumDepth'

おめでとうございます。ImageMagickの動作ディストリビューションがあり、PerlMagickを使用して画像を変換、合成、または編集する準備ができました。

Windows XP / Windows 2000

ImageMagickはすでにシステムにインストールされている必要があります。また、Windows 2000用のImageMagickソースディストリビューションが必要です。Visual C++またはJ++開発環境からのnmakeも必要です。\bin\IMagick.dllと\bin\X11.dllを、c:\perl\site\5.00502などの動的ロードパスにあるディレクトリにコピーします。

次に、次のように入力します

cd PerlMagick
perl Makefile.nt
nmake
nmake install

回帰テストの実行

インストールが正しいことを確認するには、次のように入力します

make test

Windowsでは、nmake testを使用します。PerlMagickが実行できる多くの機能を実行するためのいくつかのデモスクリプトがあります。次のように入力します

ビルドフォルダーからテストを実行するには、proveユーティリティを使用します

prove --blib blib -I `pwd` -bv ./t/read.t

cd demo
make

これで、Perlスクリプト内からPerlMagickメソッドを利用する準備ができました。

概要

PerlMagickメソッドを使用するすべてのスクリプトは、まずその名前空間内でメソッドを定義し、イメージオブジェクトをインスタンス化する必要があります。これを行うには、次のようにします

use Image::Magick;

$image = Image::Magick->new;

PerlMagickは量子を認識します。イメージオブジェクトをインスタンス化するときに、特定の量子深度をリクエストできます

use Image::Magick::Q16;

$image = Image::Magick::Q16->new;

new()メソッドは、SetAttributeと同じパラメーターを受け取ります。たとえば、

$image = Image::Magick->new(size=>'384x256');

次に、画像または画像シーケンスを読み込み、操作してから、表示または書き込む必要があります。PerlMagickの入力および出力メソッドは、画像の読み込みまたは書き込みで定義されています。画像の読み取りまたは書き込み方法に影響を与えるメソッドについては、画像属性の設定を参照してください。画像を変換するためのメソッドのリストについては、画像の操作を参照してください。画像属性の取得では、画像の属性を取得する方法について説明します。背景にサムネイルとして画像をタイル表示する方法の詳細については、画像モンタージュの作成を参照してください。最後に、一部のメソッドは、上記で説明したカテゴリのいずれにもうまく適合しません。これらのメソッドのリストについては、その他のメソッドを確認してください。

PerlMagickオブジェクトが不要になったら、破棄することを検討する必要があります。画像シーケンス内の各画像は仮想メモリに格納されます。これにより、最大でメビバイトのメモリが追加される可能性があります。PerlMagickオブジェクトを破棄すると、メモリは他のPerlメソッドで使用するために返されます。オブジェクトを破棄する推奨される方法は、undefを使用することです

undef $image;

すべての画像を削除するが、Image::Magickオブジェクトを保持するには、次のように使用します

@$image = ();

最後に、複数画像シーケンスから単一の画像を削除するには、次のように使用します

undef $image->[$x];

次のセクションでは、さまざまなPerlMagickメソッドを使用して画像シーケンスを操作する方法について説明します。

PerlMagickメソッドの一部には、Ghostscriptなどの外部プログラムが必要です。これを適切に動作させるには、PATH環境変数に明示的なパスが必要になる場合があります。たとえば（Linuxの場合）、

$ENV{PATH}' . "='/../bin:/usr/bin:/usr/local/bin';

サンプルスクリプト

開始するためのサンプルスクリプトを次に示します

#!/usr/local/bin/perl
use Image::Magick;

my($image, $x);

$image = Image::Magick->new;
$x = $image->Read('girl.png', 'logo.png', 'rose.png');
warn "$x" if "$x";

$x = $image->Crop(geometry=>'100x100+100+100');
warn "$x" if "$x";

$x = $image->Write('x.png');
warn "$x" if "$x";

スクリプトは3つの画像を読み取り、それらを切り抜いて、単一の画像をGIFアニメーションシーケンスとして書き込みます。多くの場合、シーケンスの個々の画像にアクセスする必要がある場合があります。次の例では、これがどのように行われるかを示します

#!/usr/local/bin/perl
use Image::Magick;

my($image, $p, $q);

$image = new Image::Magick;
$image->Read('x1.png');
$image->Read('j*.jpg');
$image->Read('k.miff[1, 5, 3]');
$image->Contrast();
for ($x = 0; $image->[$x]; $x++)
{
  $image->[$x]->Frame('100x200') if $image->[$x]->Get('magick') eq 'GIF';
  undef $image->[$x] if $image->[$x]->Get('columns') < 100;
}
$p = $image->[1];
$p->Draw(stroke=>'red', primitive=>'rectangle', points=>20,20 100,100');
$q = $p->Montage();
undef $image;
$q->Write('x.miff');

中央に赤いピクセルがある100 x 100ピクセルの白いキャンバスから開始するとします。次を試してください

$image = Image::Magick->new;
$image->Set(size=>'100x100');
$image->ReadImage('canvas:white');
$image->Set('pixel[49,49]'=>'red');

ここでは、(1,1)での赤色の成分の強度を半分に減らします

@pixels = $image->GetPixel(x=>1,y=>1);
$pixels[0]*=0.5;
$image->SetPixel(x=>1,y=>1,color=>\@pixels);

または、カラー画像をグレースケールに変換するとします

$image->Quantize(colorspace=>'gray');

Taipai TrueTypeフォントで画像に注釈を付けましょう

$text = 'Works like magick!';
$image->Annotate(font=>'kai.ttf', pointsize=>40, fill=>'green', text=>$text);

おそらく、画像からすべてのピクセル強度を抽出し、それらをSTDOUTに書き込みたいと考えています

@pixels = $image->GetPixels(map=>'I', height=>$height, width=>$width, normalize=>true);
binmode STDOUT;
print pack('B*',join('',@pixels));

PerlMagickオブジェクトで実行できる他の巧妙な操作には、次のようなものがあります

$i = $#$p"+1";   # return the number of images associated with object p
push(@$q, @$p);  # push the images from object p onto object q
@$p = ();        # delete the images but not the object p
$p->Convolve([1, 2, 1, 2, 4, 2, 1, 2, 1]);   # 3x3 Gaussian kernel

画像の読み込みまたは書き込み

以下のメソッドを使用して、画像または画像シーケンスを読み取り、書き込み、または表示します

読み取り/書き込みメソッド

メソッド	パラメーター	戻り値	説明
Read	1つ以上のファイル名	読み込まれた画像の数	画像または画像シーケンスを読み取る
Write	ファイル名	書き込まれた画像の数	画像または画像シーケンスを書き込む
Display	サーバー名	表示された画像の数	画像または画像シーケンスをXサーバーに表示する
Animate	サーバー名	アニメーション化された画像の数	画像シーケンスをXサーバーにアニメーション化する

便宜上、Write()、Display()、Animate()メソッドは、SetAttributeが認識するパラメーターを受け取ることができます。たとえば、

$image->Write(filename=>'image.png', compression=>'None');

メソッドRead()で標準入力から読み取るか、メソッドWrite()で標準出力に書き込む場合は、ファイル名として-を使用します

binmode STDOUT;
$image->Write('png:-');

PERLファイルハンドルからGIF形式で画像を読み取るには、次のように使用します

$image = Image::Magick->new;
open(IMAGE, 'image.gif');
$image->Read(file=>\*IMAGE);
close(IMAGE);

PERLファイルハンドルにPNG形式で画像を書き込むには、次のように使用します

$filename = "image.png";
open(IMAGE, ">$filename");
$image->Write(file=>\*IMAGE, filename=>$filename);
close(IMAGE);

注：ImageMagickとActiveState Perlディストリビューション間でCランタイムライブラリのバージョンが異なる場合、またはDLLの1つが/MTオプションでリンクされている場合、WindowsではPerlファイルハンドルからの読み取りまたは書き込みが失敗する可能性があります。詳細については、DLL境界を越えてCRTオブジェクトを渡す場合の潜在的なエラーを参照してください。

ファイル名に%0Nd、%0No、または%0Nxが表示されている場合、printf形式の指定として解釈され、指定された10進数、8進数、または16進数のシーン番号エンコードに置き換えられます。たとえば、

image%03d.miff

ファイルimage000.miff、image001.miffなどを変換します。

オプションで、任意のメソッド名にImageを追加できます。たとえば、ReadImage()はメソッドRead()のエイリアスです。

画像の操作

たとえば、メソッドReadImage()で画像を作成したら、その画像を操作する必要があります。以下は、PerlMagickで使用できるすべての画像操作メソッドのリストです。選択されたPerlMagickメソッドのサンプルがあります。画像操作メソッドの呼び出し例を次に示します

$image->Crop(geometry=>'100x100+10+20');
$image->[$x]->Frame("100x200");

また、呼び出すことができるその他の画像操作メソッドのリストを次に示します

geometry パラメータは、width および height パラメータのショートカットであることに注意してください（例：geometry=>'106x80' は width=>106, height=>80 と同等です）。

Annotate() と Draw() の両方で @filename を指定できます。これにより、ディスク上のファイルからテキストまたはグラフィックプリミティブ命令を読み込みます。例：

image->Draw(fill=>'red', primitive=>'rectangle',
 points=>'20,20 100,100  40,40 200,200  60,60 300,300');

次のものと同等です

$image->Draw(fill=>'red', primitive=>'@draw.txt');

ここで、draw.txt は、次の内容を含むディスク上のファイルです

rectangle 20, 20 100, 100
rectangle 40, 40 200, 200
rectangle 60, 60 300, 300

メソッド、Annotate()、Comment()、Draw()、Label() の text パラメータには、これらの特殊な書式文字を埋め込むことで、画像ファイル名、タイプ、幅、高さ、またはその他の画像属性を含めることができます

%b   file size
%c   comment
%d   directory
%e   filename extension
%f   filename
%g   page geometry
%h   height
%i   input filename
%k   number of unique colors
%l   label
%m   magick
%n   number of scenes
%o   output filename
%p   page number
%q   quantum depth
%r   image class and colorspace
%s   scene number
%t   top of filename
%u   unique temporary filename
%w   width
%x   x resolution
%y   y resolution
%z   image depth
%C   image compression type
%D   image dispose method
%H   page height
%Q   image compression quality
%T   image delay
%W   page width
%X   page x offset
%Y   page y offset
%@   bounding box
%#   signature
%%   a percent sign
\n   newline
\r   carriage return

例：

text=>"%m:%f %wx%h"

bird.miff というタイトルの画像で、幅が 512、高さが 480 の場合、MIFF:bird.miff 512x480 という注釈が生成されます。

オプションで、メソッド名の任意の位置に Image を追加できます。たとえば、TrimImage() はメソッド Trim() のエイリアスです。

上記にリストされた属性のほとんどは、magick に類似した属性を持っています。これらの属性の詳細については、ドキュメントを参照してください。

画像属性の設定

画像属性を設定するには、メソッド Set() を使用します。例：

$image->Set(dither=>'True');
$image->[$x]->Set(delay=>3);

この例では 'True' を使用し、このドキュメントでは '{True, False}' と記述されている場合、大文字と小文字を区別しない文字列 'True' と 'False' を使用するか、整数 1 と 0 を使用できます。

ブール属性に対して Get() を呼び出すと、Image::Magick は文字列ではなく 1 または 0 を返します。

以下は、設定できるすべての画像属性のリストです

geometry パラメータは、width および height パラメータのショートカットであることに注意してください（例：geometry=>'106x80' は width=>106, height=>80 と同等です）。

SetAttribute() は、メソッド Set() のエイリアスです。

上記にリストされた属性のほとんどは、magick に類似した属性を持っています。これらの属性の詳細については、ドキュメントを参照してください。

画像属性の取得

画像属性を取得するには、メソッド Get() を使用します。例：

($a, $b, $c) = $image->Get('colorspace', 'magick', 'adjoin');
$width = $image->[3]->Get('columns');

画像属性の設定 にリストされているすべての属性に加えて、これらの追加属性を取得できます

GetAttribute()はGet()メソッドのエイリアスです。

上記にリストされた属性のほとんどは、magick に類似した属性を持っています。これらの属性の詳細については、ドキュメントを参照してください。

画像とその再構成を比較する

Compare()メソッドを使用して、画像とその再構成の差異を数学的および視覚的に注釈付けます。このメソッドは次のパラメーターをサポートします。

比較パラメーター

パラメーター	値	説明
チャンネル	double	画像チャンネルを選択します。デフォルトはアルファを除くすべてのチャンネルです。
fuzz	double	この距離内の色は等しいと見なされます
画像	画像参照	画像の再構成
メトリック	AE、MAE、MEPP、MSE、PAE、PSNR、RMSE	このメトリックを使用して画像間の差異を測定します

この例では、ImageMagickロゴとシャープニングされた再構成を比較します。

use Image::Magick;

$logo=Image::Magick->New();
$logo->Read('logo:');
$sharp=Image::Magick->New();
$sharp->Read('logo:');
$sharp->Sharpen('0x1');
$difference=$logo->Compare(image=>$sharp, metric=>'rmse');
print $difference->Get('error'), "\n";
$difference->Display();

約0.024の報告された二乗平均平方根誤差に加えて、画像間の差異を視覚的に識別できるように、差異画像が表示されます。

画像モンタージュを作成する

Montage()メソッドを使用して、複数の個別の画像を組み合わせて合成画像を作成します。画像は合成画像上にタイル状に並べられ、オプションで個々のタイルのすぐ下に画像の名前が表示されます。たとえば、

$image->Montage(geometry=>'160x160', tile=>'2x2', texture=>'granite:');

Montage()で設定できるパラメーターのリストを次に示します。

geometry パラメータは、width および height パラメータのショートカットであることに注意してください（例：geometry=>'106x80' は width=>106, height=>80 と同等です）。

MontageImage()はMontage()メソッドのエイリアスです。

上記にリストされている属性のほとんどは、montageに類似物があります。これらの属性の詳細については、ドキュメントを参照してください。

BLOBの操作

BLOBには、ディスク上ではなくメモリ内の特定の画像フォーマットを直接表すデータが含まれています。PerlMagickは、これらの画像フォーマットのいずれかのBLOBをサポートし、BLOBを特定の画像フォーマットとの間で変換するメソッドを提供します。

BLOBメソッド

メソッド	パラメーター	戻り値	説明
ImageToBlob	任意の画像属性	それぞれの画像フォーマットの画像データの配列	画像または画像シーケンスをBLOBの配列に変換する
BlobToImage	1つ以上のBLOB	画像に変換されたBLOBの数	1つ以上のBLOBを画像に変換する

ImageToBlob()は、それぞれのフォーマットで画像データを返します。次に、それを印刷したり、ODBCデータベースに保存したり、ファイルに書き込んだり、表示プログラムにパイプしたりできます。

@blobs = $image->ImageToBlob();
open(DISPLAY,"| display -") || die;
binmode DISPLAY;
print DISPLAY $blobs[0];
close DISPLAY;

BlobToImage()メソッドは、指定されたBLOBから変換された画像または画像シーケンスを返します。

@blob=$db->GetImage();
$image=Image::Magick->new(magick=>'jpg');
$image->BlobToImage(@blob);

画像ピクセルへの直接アクセス

これらのメソッドを使用して、画像ピクセルへの直接アクセスを取得します。

画像ピクセルへの直接アクセス

メソッド	パラメーター	説明
GetAuthenticPixels	geometry=>geometry、width=>integer、height=>integer、x=>integer、y=>integer	本物のピクセルをCポインタとして返します
GetVirtualPixels	geometry=>geometry、width=>integer、height=>integer、x=>integer、y=>integer	仮想ピクセルをconst Cポインタとして返します
GetAuthenticIndexQueue		カラーマップインデックスまたは黒のピクセルをCポインタとして返します
GetVirtualIndexQueue		カラーマップインデックスまたは黒のピクセルをconst Cポインタとして返します
SyncAuthenticPixels		本物のピクセルをピクセルキャッシュに同期します

その他のメソッド

Append()メソッドは、一連の画像を追加します。たとえば、

$p = $image->Append(stack=>{true,false});

オブジェクト$imageに関連付けられているすべての画像を追加します。デフォルトでは、画像は左から右に積み重ねられます。それらを上から下に積み重ねるには、stackをTrueに設定します。

Clone()メソッドは、一連の画像をコピーします。たとえば、

$q = $p->Clone();

オブジェクト$pから$qにすべての画像をコピーします。このメソッドは、単一または複数画像のシーケンスに使用できます。

Coalesce()は、ページオフセットと破棄方法を考慮しながら、一連の画像を合成します。GIF、MIFF、およびMNGのアニメーションシーケンスは通常、画像の背景で始まり、後続の各画像はサイズとオフセットが異なります。新しい画像シーケンスは、最初の画像の仮想キャンバスと同じサイズで、シーケンス内の次の画像と合成されたすべての画像で返されます。たとえば、

$q = $p->Coalesce();

ComplexImages()メソッドは、画像シーケンスに対して複雑な数学演算を実行します。たとえば、

$p = $image->ComplexImages('conjugate');

EvaluateImages()メソッドは、一連の画像に算術、論理、または関係式を適用します。たとえば、

$p = $image->EvaluateImages('mean');

オブジェクト$imageに関連付けられているすべての画像の平均を計算します。

Features()メソッドは、指定された距離の4つの方向（水平、垂直、左、右の対角線）のそれぞれについて、画像の各チャンネルの特性を返します。特性には、角度の2次モーメント、コントラスト、相関、二乗の合計：分散、逆差モーメント、合計平均、合計分散、合計エントロピー、エントロピー、差分散、差エントロピー、相関の測定値1、相関の測定値2、および最大相関係数が含まれます。RGB、CMYK、RGBA、またはCMYKAの順（画像の種類によって異なります）。

@features = $image->Features(1);

Flatten()メソッドは、一連の画像をフラット化して返します。たとえば、

$p = $images->Flatten(background=>'none');
$p->Write('flatten.png');

画像シーケンスは、最初の画像の後に各画像を重ねて作成された単一の画像に置き換えられます。

Fx()メソッドは、一連の画像に数式を適用し、結果を返します。たとえば、

$p = $image->Fx(expression=>'(g+b)/2.0',channel=>'red');
$p->Write('fx.miff');

赤チャンネルを緑と青チャンネルの平均に置き換えます。

このメソッドの詳細については、FX、特殊効果画像オペレーターを参照してください。

Histogram()は、画像内の一意の色とそれぞれの数を返します。返される値は、赤、緑、青、不透明度、およびカウント値の配列です。

Morph()メソッドは、一連の画像をモーフィングします。画像ピクセルとサイズの両方が線形に補間され、ある画像から次の画像へのメタモーフォシスの外観を与えます。

$p = $image->Morph(frames=>integer);

ここで、framesは生成する中間画像の数です。デフォルトは1です。

Mosaic()は、画像シーケンスからモザイクを作成します。

Mogrify()メソッドは、画像操作メソッド（画像の操作）の単一のエントリーポイントです。パラメーターは、メソッドの名前と、メソッドが必要とする可能性のあるパラメーターです。たとえば、次の呼び出しは同等です。

$image->Crop('340x256+0+0');
$image->Mogrify('crop', '340x256+0+0');

MogrifyRegion()メソッドは、画像の領域に変換を適用します。これはMogrify()に似ていますが、領域ジオメトリから始まります。たとえば、画像の場所（40、50）で100x100の領域を明るくしたいとします。

$image->MogrifyRegion('100x100+40+50', 'modulate', brightness=>50);

PerceptualHash()は、視覚的に同一の画像を同じまたは類似のハッシュにマップします。これは、デジタル透かしだけでなく、画像検索、認証、インデックス作成、またはコピー検出で役立ちます。チャンネルごと、およびsRGBおよびHCLp色空間ごとに、7つのハッシュ値が返されます。たとえば、sRGB画像の場合、42個の知覚ハッシュが予想されます。

@phash = $image->PerceptualHash();

Ping()は、画像をメモリに読み込まずに画像に関する情報を返す便利なメソッドです。画像の幅、高さ、ファイルサイズ（バイト単位）、およびファイル形式を返します。複数のファイル名を指定できますが、指定できるファイルハンドルは1つだけです。

($width, $height, $size, $format) = $image->Ping('logo.png');
($width, $height, $size, $format) = $image->Ping(file=>\*IMAGE);
($width, $height, $size, $format) = $image->Ping(blob=>$blob);

これは、画像が存在するかどうか、およびその特性を照会するための、より効率的でメモリ消費量の少ない方法です。

Poly()は、画像シーケンスと対応する項（係数と次数のペア）から多項式を構築します。

$p = $image->Poly([0.5,1.0,0.25,2.0,1.0,1.0]);

PreviewImage()は、指定された画像の9つのサムネイルをタイル状に並べ、さまざまな強度で画像処理操作を適用します。これは、特定の画像処理操作に適切なパラメーターを特定するのに役立つ場合があります。次の操作から選択してください：Rotate、Shear、Roll、Hue、Saturation、Brightness、Gamma、Spiff、Dull、Grayscale、Quantize、Despeckle、ReduceNoise、AddNoise、Sharpen、Blur、Threshold、EdgeDetect、Spread、Solarize、Shade、Raise、Segment、Swirl、Implode、Wave、OilPaint、CharcoalDrawing、JPEG。次に例を示します。

$preview = $image->Preview('Gamma');
$preview->Display();

テキストの位置を完全に制御するには、フォントメトリック情報が必要です。使用してください

($x_ppem, $y_ppem, $ascender, $descender, $width, $height, $max_advance) =
  $image->QueryFontMetrics(parameters);

ここで、parametersは、Annotateメソッドの任意のパラメーターです。戻り値は次のとおりです。

1. 文字幅
2. 文字の高さ
3. アセンダー
4. ディセンダー
5. テキストの幅
6. テキストの高さ
7. 水平方向の最大アドバンス
8. 境界：x1
9. 境界：y1
10. 境界：x2
11. 境界：y2
12. 原点：x
13. 原点：y

複数行のテキストの最大テキスト幅と高さを取得するには、QueryMultilineFontMetrics()を使用します。

パラメーターを指定せずにQueryColor()を呼び出して、既知の色名のリストを返すか、1つ以上の色名を指定して、赤、緑、青、および不透明度の値を取得します。

@colors = $image->QueryColor();
($red, $green, $blue) = $image->QueryColor('cyan');
($red, $green, $blue, $alpha) = $image->QueryColor('#716baeff');

QueryColorname()は色の値を受け取り、それぞれの名前または16進数値を返します。

$name = $image->QueryColorname('rgba(80,60,0,0)');

パラメーターを指定せずにQueryFont()を呼び出して、既知のフォントのリストを返すか、1つ以上のフォント名を指定して、フォント名、説明、ファミリー、スタイル、ストレッチ、太さ、エンコーディング、ファウンダリ、フォーマット、メトリック、およびグリフの値を取得します。

@fonts = $image->QueryFont();
$weight = ($image->QueryFont('Helvetica'))[5];

パラメーターを指定せずにQueryFormat()を呼び出して、既知の画像フォーマットのリストを返すか、1つ以上のフォーマット名を指定して、隣接、BLOBサポート、raw、デコーダー、エンコーダー、説明、およびモジュールの属性を取得します。

@formats = $image->QueryFormat();
($adjoin, $blob_support, $raw, $decoder, $encoder, $description, $module) =
  $image->QueryFormat('gif');

画像フォーマット名を指定してMagickToMime()を呼び出し、tifからimage/tiffなどのMIMEタイプを取得します。

$mime = $image->MagickToMime('tif');

RemoteCommand()を使用して、すでに実行中のdisplayまたはanimateアプリケーションにコマンドを送信します。唯一のパラメーターは、表示またはアニメーション化する画像ファイルの名前です。

$image->RemoteCommand('image.jpg');

Smush()メソッドは、一連の画像を一緒に押しつぶします。たとえば、

$p = $image->Smush(stack=>{true,false},offset=>integer);

オブジェクト$imageに関連付けられているすべての画像を一緒に押しつぶします。デフォルトでは、画像は左から右に押しつぶされます。それらを上から下に押しつぶすには、stackをTrueに設定します。

Statistics()は、画像の各チャンネルの画像統計を返します。返される値は、深さ、最小値、最大値、平均値、標準偏差、尖度、歪度、およびエントロピー値の配列（RGB、CMYK、RGBA、またはCMYKAの順（画像の種類によって異なります））です。

@statistics = $image->Statistics();

最後に、Transform() メソッドは、1 つ以上の画像を切り抜きまたはリサイズするための完全修飾されたジオメトリ指定を受け入れます。例:

$p = $image->Transform(crop=>'100x100+0+0');

オプションで、上記メソッド名の末尾に Image を追加できます。たとえば、PingImage() はメソッド Ping() のエイリアスです。

例外処理

PerlMagick のすべてのメソッドは、成功時に未定義の文字列コンテキストを返します。問題が発生した場合、エラーは数値ステータスコードが埋め込まれた文字列として返されます。400 未満のステータスコードは警告です。これは、操作が完了しなかったものの、ある程度回復可能であることを意味します。400 以上の数値コードはエラーであり、操作が完全に失敗したことを示します。以下は、異なるメソッドで例外がどのように返されるかを示しています。

数値 (例: Read(), Write()) を返すメソッド

$x = $image->Read(...);
warn "$x" if "$x";      # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number
print 0+$x;             # print the number of images read

画像 (例: Resize(), Crop()) を操作するメソッド

$x = $image->Crop(...);
warn "$x" if "$x";      # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number

画像を返すメソッド (EvaluateSequence(), Montage(), Clone()) は、次のようにエラーをチェックする必要があります。

$x = $image->Montage(...);
warn "$x" if !ref($x);  # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number

以下にエラーメッセージの例を示します。

Error 400: Memory allocation failed

エラーと警告コードの完全なリストを確認してください。

以下に、数値ステータスコードを使用する方法を示します。

$x = $image->Read('rose.png');
$x =~ /(\d+)/;
die "unable to continue" if ($1 == ResourceLimitError);

定数

PerlMagick には、以下の定数が含まれています。

BlobError
BlobWarning
CacheError
CacheWarning
CoderError
CoderWarning
ConfigureError
ConfigureWarning
CorruptImageError
CorruptImageWarning
DelegateError
DelegateWarning
DrawError
DrawWarning
ErrorException
FatalErrorException
FileOpenError
FileOpenWarning
ImageError
ImageWarning
MissingDelegateError
MissingDelegateWarning
ModuleError
ModuleWarning
Opaque
OptionError
OptionWarning
QuantumDepth
QuantumRange
RegistryError
RegistryWarning
ResourceLimitError
ResourceLimitWarning
StreamError
StreamWarning
Success
Transparent
TypeError
TypeWarning
WarningException
XServerError
XServerWarning

これらには次のようにアクセスできます。

Image::Magick->QuantumDepth